【Excel VBA】配列の動的確保（配列の要素数を増やす方法）

Public Sub addArrayElement()

    Dim arr() As String ' 文字列型配列

    ' 配列の 0番目を確保し、文字列 "A"を代入
    ReDim arr(0)
    arr(0) = "A"

    ' 配列の 1番目を確保し、文字列 "B"を代入
    ReDim Preserve arr(1)
    arr(1) = "B"

End Sub

Public Sub addArrayElement()

    Dim arr() As String ' 文字列型配列

    ' 配列の 1次元目を2、2次元目を0番の要素を確保する。
    ReDim arr(2, 0)
    arr(0, 0) = "A"
    arr(1, 0) = "B"
    arr(2, 0) = "C"

    ' 2次元目を拡張する。
    ReDim Preserve arr(2, 1)
    arr(0, 1) = "X"
    arr(1, 1) = "Y"
    arr(2, 1) = "Z"

End Sub

Public Sub main()

    Dim arr() As Variant        ' 配列
    Dim endRowIndex As Long     ' Sheet1 最終行番号
    Dim cellValue As Variant    ' セルの値

    ' Sheet1の最終行を取得する
    endRowIndex = ThisWorkbook.Worksheets(1).UsedRange.Rows.Count

    Dim i As Long
    For i = 1 To endRowIndex

        ' *** Sheet1 1列目を最終行分ループする ***

        ' セルの値を取得
        cellValue = ThisWorkbook.Worksheets(1).Cells(i, 1).Value

        Call addArrayElementForVariant(arr, cellValue)
    Next i

End Sub

Public Sub addArrayElementForVariant(ByRef arr() As Variant, ByVal element As Variant)

    If (Not arr) = -1 Then

        ' 配列が空の場合
        ReDim arr(0)
    Else

        ' 配列が空ではない場合
        ReDim Preserve arr(UBound(arr) - LBound(arr) + 1)
    End If

    ' 配列に値を格納
    arr(UBound(arr) - LBound(arr)) = element
End Sub