【Excel VBA】ファイル・フォルダのサイズを取得する（FileLen/Size）

Public Sub getFileSize()
    Dim filePath As String
    Dim fileSize As Long

    ' ファイルパスをセット
    filePath = "C:\vba-hack\vba\TestFile.txt"

    ' ファイルサイズを取得
    fileSize = FileLen(filePath)

    ' セルに情報を書き出し
    Range("A1").Value = filePath    ' ファイルパス
    Range("B1").Value = fileSize    ' ファイルサイズ
End Sub

Public Sub getFileSizeForTargetFolder()
    Dim fso As New FileSystemObject ' FileSystemObjectインスタンス
    Dim myFolder As Folder          ' Folderオブジェクト
    Dim myFile As File              ' Fileオブジェクト
    Dim loopCnt As Long             ' ループカウンタ

    ' フォルダオブジェクトを取得
    Set myFolder = fso.GetFolder("C:\vba-hack\vba")

    ' フォルダ配下のファイル数分ループ
    loopCnt = 1
    For Each myFile In myFolder.Files

        Cells(loopCnt, 1).Value = myFile.Name   ' ファイル名
        Cells(loopCnt, 2).Value = myFile.Size   ' ファイルサイズ
        loopCnt = loopCnt + 1
    Next myFile
End Sub

Public Sub getMBFileSizeForTargetFolder()
    Dim fso As New FileSystemObject ' FileSystemObjectインスタンス
    Dim myFolder As Folder          ' Folderオブジェクト
    Dim myFile As File              ' Fileオブジェクト
    Dim loopCnt As Long             ' ループカウンタ

    ' フォルダオブジェクトを取得
    Set myFolder = fso.GetFolder("C:\vba-hack\vba")

    ' フォルダ配下のファイル数分ループ
    loopCnt = 1
    For Each myFile In myFolder.Files

        Cells(loopCnt, 1).Value = myFile.Name               ' ファイル名
        Cells(loopCnt, 2).Value = myFile.Size / (1024 ^ 2)  ' ファイルサイズ
        loopCnt = loopCnt + 1
    Next myFile
End Sub

Public Sub getFolderSizeForSubFolder()
    Dim fso As New FileSystemObject ' FileSystemObjectインスタンス
    Dim targetFolder As Folder      ' 対象フォルダ
    Dim subFolder As Folder         ' サブフォルダ
    Dim loopCnt As Long             ' ループカウンタ

    ' フォルダオブジェクトを取得
    Set targetFolder = fso.GetFolder("C:\vba-hack")

    ' フォルダ配下のフォルダ数分ループ
    loopCnt = 1
    For Each subFolder In targetFolder.SubFolders

        Cells(loopCnt, 1).Value = subFolder.Name    ' フォルダ名
        Cells(loopCnt, 2).Value = subFolder.Size    ' フォルダサイズ
        loopCnt = loopCnt + 1
    Next subFolder
End Sub